4.9) Sintetizador de Som (Piezo + Arduino)

Este exemplo usa um atuador Piezo elétrico para tocar uma melodia. Ele envia uma onda quadrada para a frequência apropriada do piezo, gerando o tom correspondente.
O cálculo dos tons é feito a partir de uma operação matemática:

timeHigh = período / 2 = 1 / (2 * Frequência do tom)

Os diferentes tons estão descritos na tabela abaixo:

nota  frequência  período    timeHigh
c       261 Hz       3830       1915 
d       294 Hz       3400       1700 
e       329 Hz       3038       151  
f       349 Hz       2864       1432 
g       392 Hz       2550       1275 
a       440 Hz       2272       1136 
b       493 Hz       2028       1014 
C       523 Hz       1912        956   

Circuito:

Os Piezos têm polaridade. Peças comerciais normalmente têm um lado vermelho (positivo) e outro preto (negativo). Conecte o cabo vermelho no pino digital 9 e o cabo preto ao terra. Às vezes é possível adquirir elementos Piezo sem a capa plástica, e se parecem a um disco metálico.

Um Piezo conectado ao pino 9, e depois ao GND.

Código:

_______________________________________________________________________________________

int speakerPin = 9;

int length = 15; // the number of notes
char notes[] = "ccggaagffeeddc "; // a space represents a rest
int beats[] = { 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 1, 1, 2, 4 };
int tempo = 300;

void playTone(int tone, int duration) {
  for (long i = 0; i < duration * 1000L; i += tone * 2) {
    digitalWrite(speakerPin, HIGH);
    delayMicroseconds(tone);
    digitalWrite(speakerPin, LOW);
    delayMicroseconds(tone);
  }
}

void playNote(char note, int duration) {
  char names[] = { 'c', 'd', 'e', 'f', 'g', 'a', 'b', 'C' };
  int tones[] = { 1915, 1700, 1519, 1432, 1275, 1136, 1014, 956 };

  // play the tone corresponding to the note name
  for (int i = 0; i < 8; i++) {
    if (names[i] == note) {
      playTone(tones[i], duration);
    }
  }
}

void setup() {
  pinMode(speakerPin, OUTPUT);
}

void loop() {
  for (int i = 0; i < length; i++) {
    if (notes[i] == ' ') {
      delay(beats[i] * tempo); // rest
    } else {
      playNote(notes[i], beats[i] * tempo);
    }

    // pause between notes
    delay(tempo / 2); 
  }
}

Desperte Sua Imaginação: